572 lines
20 KiB
Plaintext
572 lines
20 KiB
Plaintext
|
|
|
|
# http://autoconf-archive.cryp.to/acx_pthread.html
|
|
# Copyright © 2006 Steven G. Johnson <stevenj@alum.mit.edu>
|
|
AC_DEFUN([ACX_PTHREAD], [
|
|
AC_REQUIRE([AC_CANONICAL_HOST])
|
|
AC_LANG_SAVE
|
|
AC_LANG_C
|
|
acx_pthread_ok=no
|
|
|
|
# We used to check for pthread.h first, but this fails if pthread.h
|
|
# requires special compiler flags (e.g. on True64 or Sequent).
|
|
# It gets checked for in the link test anyway.
|
|
|
|
# First of all, check if the user has set any of the PTHREAD_LIBS,
|
|
# etcetera environment variables, and if threads linking works using
|
|
# them:
|
|
if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
|
|
save_CFLAGS="$CFLAGS"
|
|
CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
|
|
save_LIBS="$LIBS"
|
|
LIBS="$PTHREAD_LIBS $LIBS"
|
|
AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
|
|
AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
|
|
AC_MSG_RESULT($acx_pthread_ok)
|
|
if test x"$acx_pthread_ok" = xno; then
|
|
PTHREAD_LIBS=""
|
|
PTHREAD_CFLAGS=""
|
|
fi
|
|
LIBS="$save_LIBS"
|
|
CFLAGS="$save_CFLAGS"
|
|
fi
|
|
|
|
# We must check for the threads library under a number of different
|
|
# names; the ordering is very important because some systems
|
|
# (e.g. DEC) have both -lpthread and -lpthreads, where one of the
|
|
# libraries is broken (non-POSIX).
|
|
|
|
# Create a list of thread flags to try. Items starting with a "-" are
|
|
# C compiler flags, and other items are library names, except for "none"
|
|
# which indicates that we try without any flags at all, and "pthread-config"
|
|
# which is a program returning the flags for the Pth emulation library.
|
|
|
|
acx_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
|
|
|
|
# The ordering *is* (sometimes) important. Some notes on the
|
|
# individual items follow:
|
|
|
|
# pthreads: AIX (must check this before -lpthread)
|
|
# none: in case threads are in libc; should be tried before -Kthread and
|
|
# other compiler flags to prevent continual compiler warnings
|
|
# -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
|
|
# -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
|
|
# lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
|
|
# -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
|
|
# -pthreads: Solaris/gcc
|
|
# -mthreads: Mingw32/gcc, Lynx/gcc
|
|
# -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
|
|
# doesn't hurt to check since this sometimes defines pthreads too;
|
|
# also defines -D_REENTRANT)
|
|
# ... -mt is also the pthreads flag for HP/aCC
|
|
# pthread: Linux, etcetera
|
|
# --thread-safe: KAI C++
|
|
# pthread-config: use pthread-config program (for GNU Pth library)
|
|
|
|
case "${host_cpu}-${host_os}" in
|
|
*solaris*)
|
|
|
|
# On Solaris (at least, for some versions), libc contains stubbed
|
|
# (non-functional) versions of the pthreads routines, so link-based
|
|
# tests will erroneously succeed. (We need to link with -pthreads/-mt/
|
|
# -lpthread.) (The stubs are missing pthread_cleanup_push, or rather
|
|
# a function called by this macro, so we could check for that, but
|
|
# who knows whether they'll stub that too in a future libc.) So,
|
|
# we'll just look for -pthreads and -lpthread first:
|
|
|
|
acx_pthread_flags="-pthreads pthread -mt -pthread $acx_pthread_flags"
|
|
;;
|
|
esac
|
|
|
|
if test x"$acx_pthread_ok" = xno; then
|
|
for flag in $acx_pthread_flags; do
|
|
|
|
case $flag in
|
|
none)
|
|
AC_MSG_CHECKING([whether pthreads work without any flags])
|
|
;;
|
|
|
|
-*)
|
|
AC_MSG_CHECKING([whether pthreads work with $flag])
|
|
PTHREAD_CFLAGS="$flag"
|
|
;;
|
|
|
|
pthread-config)
|
|
AC_CHECK_PROG(acx_pthread_config, pthread-config, yes, no)
|
|
if test x"$acx_pthread_config" = xno; then continue; fi
|
|
PTHREAD_CFLAGS="`pthread-config --cflags`"
|
|
PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
|
|
;;
|
|
|
|
*)
|
|
AC_MSG_CHECKING([for the pthreads library -l$flag])
|
|
PTHREAD_LIBS="-l$flag"
|
|
;;
|
|
esac
|
|
|
|
save_LIBS="$LIBS"
|
|
save_CFLAGS="$CFLAGS"
|
|
LIBS="$PTHREAD_LIBS $LIBS"
|
|
CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
|
|
|
|
# Check for various functions. We must include pthread.h,
|
|
# since some functions may be macros. (On the Sequent, we
|
|
# need a special flag -Kthread to make this header compile.)
|
|
# We check for pthread_join because it is in -lpthread on IRIX
|
|
# while pthread_create is in libc. We check for pthread_attr_init
|
|
# due to DEC craziness with -lpthreads. We check for
|
|
# pthread_cleanup_push because it is one of the few pthread
|
|
# functions on Solaris that doesn't have a non-functional libc stub.
|
|
# We try pthread_create on general principles.
|
|
AC_TRY_LINK([#include <pthread.h>],
|
|
[pthread_t th; pthread_join(th, 0);
|
|
pthread_attr_init(0); pthread_cleanup_push(0, 0);
|
|
pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
|
|
[acx_pthread_ok=yes])
|
|
|
|
LIBS="$save_LIBS"
|
|
CFLAGS="$save_CFLAGS"
|
|
|
|
AC_MSG_RESULT($acx_pthread_ok)
|
|
if test "x$acx_pthread_ok" = xyes; then
|
|
break;
|
|
fi
|
|
|
|
PTHREAD_LIBS=""
|
|
PTHREAD_CFLAGS=""
|
|
done
|
|
fi
|
|
|
|
# Various other checks:
|
|
if test "x$acx_pthread_ok" = xyes; then
|
|
save_LIBS="$LIBS"
|
|
LIBS="$PTHREAD_LIBS $LIBS"
|
|
save_CFLAGS="$CFLAGS"
|
|
CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
|
|
|
|
# Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
|
|
AC_MSG_CHECKING([for joinable pthread attribute])
|
|
attr_name=unknown
|
|
for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
|
|
AC_TRY_LINK([#include <pthread.h>], [int attr=$attr; return attr;],
|
|
[attr_name=$attr; break])
|
|
done
|
|
AC_MSG_RESULT($attr_name)
|
|
if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
|
|
AC_DEFINE_UNQUOTED(PTHREAD_CREATE_JOINABLE, $attr_name,
|
|
[Define to necessary symbol if this constant
|
|
uses a non-standard name on your system.])
|
|
fi
|
|
|
|
AC_MSG_CHECKING([if more special flags are required for pthreads])
|
|
flag=no
|
|
case "${host_cpu}-${host_os}" in
|
|
*-aix* | *-freebsd* | *-darwin*) flag="-D_THREAD_SAFE";;
|
|
*solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
|
|
esac
|
|
AC_MSG_RESULT(${flag})
|
|
if test "x$flag" != xno; then
|
|
PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"
|
|
fi
|
|
|
|
LIBS="$save_LIBS"
|
|
CFLAGS="$save_CFLAGS"
|
|
|
|
# More AIX lossage: must compile with xlc_r or cc_r
|
|
if test x"$GCC" != xyes; then
|
|
AC_CHECK_PROGS(PTHREAD_CC, xlc_r cc_r, ${CC})
|
|
else
|
|
PTHREAD_CC=$CC
|
|
fi
|
|
else
|
|
PTHREAD_CC="$CC"
|
|
fi
|
|
|
|
AC_SUBST(PTHREAD_LIBS)
|
|
AC_SUBST(PTHREAD_CFLAGS)
|
|
AC_SUBST(PTHREAD_CC)
|
|
|
|
# Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
|
|
if test x"$acx_pthread_ok" = xyes; then
|
|
ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
|
|
:
|
|
else
|
|
acx_pthread_ok=no
|
|
$2
|
|
fi
|
|
AC_LANG_RESTORE
|
|
])dnl ACX_PTHREAD
|
|
|
|
|
|
dnl
|
|
dnl nicked from wxwin.m4
|
|
dnl
|
|
|
|
|
|
dnl ---------------------------------------------------------------------------
|
|
dnl Macros for wxWidgets detection. Typically used in configure.in as:
|
|
dnl
|
|
dnl AC_ARG_ENABLE(...)
|
|
dnl AC_ARG_WITH(...)
|
|
dnl ...
|
|
dnl AM_OPTIONS_WXCONFIG
|
|
dnl ...
|
|
dnl ...
|
|
dnl AM_PATH_WXCONFIG(2.6.0, wxWin=1)
|
|
dnl if test "$wxWin" != 1; then
|
|
dnl AC_MSG_ERROR([
|
|
dnl wxWidgets must be installed on your system
|
|
dnl but wx-config script couldn't be found.
|
|
dnl
|
|
dnl Please check that wx-config is in path, the directory
|
|
dnl where wxWidgets libraries are installed (returned by
|
|
dnl 'wx-config --libs' command) is in LD_LIBRARY_PATH or
|
|
dnl equivalent variable and wxWidgets version is 2.3.4 or above.
|
|
dnl ])
|
|
dnl fi
|
|
dnl CPPFLAGS="$CPPFLAGS $WX_CPPFLAGS"
|
|
dnl CXXFLAGS="$CXXFLAGS $WX_CXXFLAGS_ONLY"
|
|
dnl CFLAGS="$CFLAGS $WX_CFLAGS_ONLY"
|
|
dnl
|
|
dnl LIBS="$LIBS $WX_LIBS"
|
|
dnl ---------------------------------------------------------------------------
|
|
|
|
dnl ---------------------------------------------------------------------------
|
|
dnl AM_OPTIONS_WXCONFIG
|
|
dnl
|
|
dnl adds support for --wx-prefix, --wx-exec-prefix, --with-wxdir and
|
|
dnl --wx-config command line options
|
|
dnl ---------------------------------------------------------------------------
|
|
|
|
AC_DEFUN([AM_OPTIONS_WXCONFIG],
|
|
[
|
|
AC_ARG_WITH(wxdir,
|
|
[ --with-wxdir=PATH Use uninstalled version of wxWidgets in PATH],
|
|
[ wx_config_name="$withval/wx-config"
|
|
wx_config_args="--inplace"])
|
|
AC_ARG_WITH(wx-config,
|
|
[ --with-wx-config=CONFIG wx-config script to use (optional)],
|
|
wx_config_name="$withval" )
|
|
AC_ARG_WITH(wx-prefix,
|
|
[ --with-wx-prefix=PREFIX Prefix where wxWidgets is installed (optional)],
|
|
wx_config_prefix="$withval", wx_config_prefix="")
|
|
AC_ARG_WITH(wx-exec-prefix,
|
|
[ --with-wx-exec-prefix=PREFIX
|
|
Exec prefix where wxWidgets is installed (optional)],
|
|
wx_config_exec_prefix="$withval", wx_config_exec_prefix="")
|
|
])
|
|
|
|
dnl Helper macro for checking if wx version is at least $1.$2.$3, set's
|
|
dnl wx_ver_ok=yes if it is:
|
|
AC_DEFUN([_WX_PRIVATE_CHECK_VERSION],
|
|
[
|
|
wx_ver_ok=""
|
|
if test "x$WX_VERSION" != x ; then
|
|
if test $wx_config_major_version -gt $1; then
|
|
wx_ver_ok=yes
|
|
else
|
|
if test $wx_config_major_version -eq $1; then
|
|
if test $wx_config_minor_version -gt $2; then
|
|
wx_ver_ok=yes
|
|
else
|
|
if test $wx_config_minor_version -eq $2; then
|
|
if test $wx_config_micro_version -ge $3; then
|
|
wx_ver_ok=yes
|
|
fi
|
|
fi
|
|
fi
|
|
fi
|
|
fi
|
|
fi
|
|
])
|
|
|
|
dnl ---------------------------------------------------------------------------
|
|
dnl AM_PATH_WXCONFIG(VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND
|
|
dnl [, WX-LIBS [, ADDITIONAL-WX-CONFIG-FLAGS]]]])
|
|
dnl
|
|
dnl Test for wxWidgets, and define WX_C*FLAGS, WX_LIBS and WX_LIBS_STATIC
|
|
dnl (the latter is for static linking against wxWidgets). Set WX_CONFIG_NAME
|
|
dnl environment variable to override the default name of the wx-config script
|
|
dnl to use. Set WX_CONFIG_PATH to specify the full path to wx-config - in this
|
|
dnl case the macro won't even waste time on tests for its existence.
|
|
dnl
|
|
dnl Optional WX-LIBS argument contains comma- or space-separated list of
|
|
dnl wxWidgets libraries to link against (it may include contrib libraries). If
|
|
dnl it is not specified then WX_LIBS and WX_LIBS_STATIC will contain flags to
|
|
dnl link with all of the core wxWidgets libraries.
|
|
dnl
|
|
dnl Optional ADDITIONAL-WX-CONFIG-FLAGS argument is appended to wx-config
|
|
dnl invocation command in present. It can be used to fine-tune lookup of
|
|
dnl best wxWidgets build available.
|
|
dnl
|
|
dnl Example use:
|
|
dnl AM_PATH_WXCONFIG([2.6.0], [wxWin=1], [wxWin=0], [html,core,net]
|
|
dnl [--unicode --debug])
|
|
dnl ---------------------------------------------------------------------------
|
|
|
|
dnl
|
|
dnl Get the cflags and libraries from the wx-config script
|
|
dnl
|
|
AC_DEFUN([AM_PATH_WXCONFIG],
|
|
[
|
|
dnl do we have wx-config name: it can be wx-config or wxd-config or ...
|
|
if test x${WX_CONFIG_NAME+set} != xset ; then
|
|
WX_CONFIG_NAME=wx-config
|
|
fi
|
|
|
|
if test "x$wx_config_name" != x ; then
|
|
WX_CONFIG_NAME="$wx_config_name"
|
|
fi
|
|
|
|
dnl deal with optional prefixes
|
|
if test x$wx_config_exec_prefix != x ; then
|
|
wx_config_args="$wx_config_args --exec-prefix=$wx_config_exec_prefix"
|
|
WX_LOOKUP_PATH="$wx_config_exec_prefix/bin"
|
|
fi
|
|
if test x$wx_config_prefix != x ; then
|
|
wx_config_args="$wx_config_args --prefix=$wx_config_prefix"
|
|
WX_LOOKUP_PATH="$WX_LOOKUP_PATH:$wx_config_prefix/bin"
|
|
fi
|
|
if test "$cross_compiling" = "yes"; then
|
|
wx_config_args="$wx_config_args --host=$host_alias"
|
|
fi
|
|
|
|
dnl don't search the PATH if WX_CONFIG_NAME is absolute filename
|
|
if test -x "$WX_CONFIG_NAME" ; then
|
|
AC_MSG_CHECKING(for wx-config)
|
|
WX_CONFIG_PATH="$WX_CONFIG_NAME"
|
|
AC_MSG_RESULT($WX_CONFIG_PATH)
|
|
else
|
|
AC_PATH_PROG(WX_CONFIG_PATH, $WX_CONFIG_NAME, no, "$WX_LOOKUP_PATH:$PATH")
|
|
fi
|
|
|
|
if test "$WX_CONFIG_PATH" != "no" ; then
|
|
WX_VERSION=""
|
|
|
|
min_wx_version=ifelse([$1], ,2.2.1,$1)
|
|
if test -z "$5" ; then
|
|
AC_MSG_CHECKING([for wxWidgets version >= $min_wx_version])
|
|
else
|
|
AC_MSG_CHECKING([for wxWidgets version >= $min_wx_version ($5)])
|
|
fi
|
|
|
|
WX_CONFIG_WITH_ARGS="$WX_CONFIG_PATH $wx_config_args $5 $4"
|
|
|
|
WX_VERSION=`$WX_CONFIG_WITH_ARGS --version 2>/dev/null`
|
|
wx_config_major_version=`echo $WX_VERSION | \
|
|
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
|
|
wx_config_minor_version=`echo $WX_VERSION | \
|
|
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
|
|
wx_config_micro_version=`echo $WX_VERSION | \
|
|
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
|
|
|
|
wx_requested_major_version=`echo $min_wx_version | \
|
|
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
|
|
wx_requested_minor_version=`echo $min_wx_version | \
|
|
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
|
|
wx_requested_micro_version=`echo $min_wx_version | \
|
|
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
|
|
|
|
_WX_PRIVATE_CHECK_VERSION([$wx_requested_major_version],
|
|
[$wx_requested_minor_version],
|
|
[$wx_requested_micro_version])
|
|
|
|
if test -n "$wx_ver_ok"; then
|
|
|
|
AC_MSG_RESULT(yes (version $WX_VERSION))
|
|
WX_LIBS=`$WX_CONFIG_WITH_ARGS --libs`
|
|
|
|
dnl is this even still appropriate? --static is a real option now
|
|
dnl and WX_CONFIG_WITH_ARGS is likely to contain it if that is
|
|
dnl what the user actually wants, making this redundant at best.
|
|
dnl For now keep it in case anyone actually used it in the past.
|
|
AC_MSG_CHECKING([for wxWidgets static library])
|
|
WX_LIBS_STATIC=`$WX_CONFIG_WITH_ARGS --static --libs 2>/dev/null`
|
|
if test "x$WX_LIBS_STATIC" = "x"; then
|
|
AC_MSG_RESULT(no)
|
|
else
|
|
AC_MSG_RESULT(yes)
|
|
fi
|
|
|
|
dnl starting with version 2.2.6 wx-config has --cppflags argument
|
|
wx_has_cppflags=""
|
|
if test $wx_config_major_version -gt 2; then
|
|
wx_has_cppflags=yes
|
|
else
|
|
if test $wx_config_major_version -eq 2; then
|
|
if test $wx_config_minor_version -gt 2; then
|
|
wx_has_cppflags=yes
|
|
else
|
|
if test $wx_config_minor_version -eq 2; then
|
|
if test $wx_config_micro_version -ge 6; then
|
|
wx_has_cppflags=yes
|
|
fi
|
|
fi
|
|
fi
|
|
fi
|
|
fi
|
|
|
|
dnl starting with version 2.7.0 wx-config has --rescomp option
|
|
wx_has_rescomp=""
|
|
if test $wx_config_major_version -gt 2; then
|
|
wx_has_rescomp=yes
|
|
else
|
|
if test $wx_config_major_version -eq 2; then
|
|
if test $wx_config_minor_version -ge 7; then
|
|
wx_has_rescomp=yes
|
|
fi
|
|
fi
|
|
fi
|
|
if test "x$wx_has_rescomp" = x ; then
|
|
dnl cannot give any useful info for resource compiler
|
|
WX_RESCOMP=
|
|
else
|
|
WX_RESCOMP=`$WX_CONFIG_WITH_ARGS --rescomp`
|
|
fi
|
|
|
|
if test "x$wx_has_cppflags" = x ; then
|
|
dnl no choice but to define all flags like CFLAGS
|
|
WX_CFLAGS=`$WX_CONFIG_WITH_ARGS --cflags`
|
|
WX_CPPFLAGS=$WX_CFLAGS
|
|
WX_CXXFLAGS=$WX_CFLAGS
|
|
|
|
WX_CFLAGS_ONLY=$WX_CFLAGS
|
|
WX_CXXFLAGS_ONLY=$WX_CFLAGS
|
|
else
|
|
dnl we have CPPFLAGS included in CFLAGS included in CXXFLAGS
|
|
WX_CPPFLAGS=`$WX_CONFIG_WITH_ARGS --cppflags`
|
|
WX_CXXFLAGS=`$WX_CONFIG_WITH_ARGS --cxxflags`
|
|
WX_CFLAGS=`$WX_CONFIG_WITH_ARGS --cflags`
|
|
|
|
WX_CFLAGS_ONLY=`echo $WX_CFLAGS | sed "s@^$WX_CPPFLAGS *@@"`
|
|
WX_CXXFLAGS_ONLY=`echo $WX_CXXFLAGS | sed "s@^$WX_CFLAGS *@@"`
|
|
fi
|
|
|
|
ifelse([$2], , :, [$2])
|
|
|
|
else
|
|
|
|
if test "x$WX_VERSION" = x; then
|
|
dnl no wx-config at all
|
|
AC_MSG_RESULT(no)
|
|
else
|
|
AC_MSG_RESULT(no (version $WX_VERSION is not new enough))
|
|
fi
|
|
|
|
WX_CFLAGS=""
|
|
WX_CPPFLAGS=""
|
|
WX_CXXFLAGS=""
|
|
WX_LIBS=""
|
|
WX_LIBS_STATIC=""
|
|
WX_RESCOMP=""
|
|
ifelse([$3], , :, [$3])
|
|
|
|
fi
|
|
else
|
|
|
|
WX_CFLAGS=""
|
|
WX_CPPFLAGS=""
|
|
WX_CXXFLAGS=""
|
|
WX_LIBS=""
|
|
WX_LIBS_STATIC=""
|
|
WX_RESCOMP=""
|
|
|
|
ifelse([$3], , :, [$3])
|
|
|
|
fi
|
|
|
|
AC_SUBST(WX_CPPFLAGS)
|
|
AC_SUBST(WX_CFLAGS)
|
|
AC_SUBST(WX_CXXFLAGS)
|
|
AC_SUBST(WX_CFLAGS_ONLY)
|
|
AC_SUBST(WX_CXXFLAGS_ONLY)
|
|
AC_SUBST(WX_LIBS)
|
|
AC_SUBST(WX_LIBS_STATIC)
|
|
AC_SUBST(WX_VERSION)
|
|
AC_SUBST(WX_RESCOMP)
|
|
])
|
|
|
|
dnl ---------------------------------------------------------------------------
|
|
dnl Get information on the wxrc program for making C++, Python and xrs
|
|
dnl resource files.
|
|
dnl
|
|
dnl AC_ARG_ENABLE(...)
|
|
dnl AC_ARG_WITH(...)
|
|
dnl ...
|
|
dnl AM_OPTIONS_WXCONFIG
|
|
dnl ...
|
|
dnl AM_PATH_WXCONFIG(2.6.0, wxWin=1)
|
|
dnl if test "$wxWin" != 1; then
|
|
dnl AC_MSG_ERROR([
|
|
dnl wxWidgets must be installed on your system
|
|
dnl but wx-config script couldn't be found.
|
|
dnl
|
|
dnl Please check that wx-config is in path, the directory
|
|
dnl where wxWidgets libraries are installed (returned by
|
|
dnl 'wx-config --libs' command) is in LD_LIBRARY_PATH or
|
|
dnl equivalent variable and wxWidgets version is 2.6.0 or above.
|
|
dnl ])
|
|
dnl fi
|
|
dnl
|
|
dnl AM_PATH_WXRC([HAVE_WXRC=1], [HAVE_WXRC=0])
|
|
dnl if test "x$HAVE_WXRC" != x1; then
|
|
dnl AC_MSG_ERROR([
|
|
dnl The wxrc program was not installed or not found.
|
|
dnl
|
|
dnl Please check the wxWidgets installation.
|
|
dnl ])
|
|
dnl fi
|
|
dnl
|
|
dnl CPPFLAGS="$CPPFLAGS $WX_CPPFLAGS"
|
|
dnl CXXFLAGS="$CXXFLAGS $WX_CXXFLAGS_ONLY"
|
|
dnl CFLAGS="$CFLAGS $WX_CFLAGS_ONLY"
|
|
dnl
|
|
dnl LDFLAGS="$LDFLAGS $WX_LIBS"
|
|
dnl ---------------------------------------------------------------------------
|
|
|
|
|
|
|
|
dnl ---------------------------------------------------------------------------
|
|
dnl AM_PATH_WXRC([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
|
|
dnl
|
|
dnl Test for wxWidgets' wxrc program for creating either C++, Python or XRS
|
|
dnl resources. The variable WXRC will be set and substituted in the configure
|
|
dnl script and Makefiles.
|
|
dnl
|
|
dnl Example use:
|
|
dnl AM_PATH_WXRC([wxrc=1], [wxrc=0])
|
|
dnl ---------------------------------------------------------------------------
|
|
|
|
dnl
|
|
dnl wxrc program from the wx-config script
|
|
dnl
|
|
AC_DEFUN([AM_PATH_WXRC],
|
|
[
|
|
AC_ARG_VAR([WXRC], [Path to wxWidget's wxrc resource compiler])
|
|
|
|
if test "x$WX_CONFIG_NAME" = x; then
|
|
AC_MSG_ERROR([The wxrc tests must run after wxWidgets test.])
|
|
else
|
|
|
|
AC_MSG_CHECKING([for wxrc])
|
|
|
|
if test "x$WXRC" = x ; then
|
|
dnl wx-config --utility is a new addition to wxWidgets:
|
|
_WX_PRIVATE_CHECK_VERSION(2,5,3)
|
|
if test -n "$wx_ver_ok"; then
|
|
WXRC=`$WX_CONFIG_WITH_ARGS --utility=wxrc`
|
|
fi
|
|
fi
|
|
|
|
if test "x$WXRC" = x ; then
|
|
AC_MSG_RESULT([not found])
|
|
ifelse([$2], , :, [$2])
|
|
else
|
|
AC_MSG_RESULT([$WXRC])
|
|
ifelse([$1], , :, [$1])
|
|
fi
|
|
|
|
AC_SUBST(WXRC)
|
|
fi
|
|
])
|